合并具有不同时间戳格式的日志文件

此解决方案使用awk脚本将第一个文件中的日期转换为自该纪元以来的秒数，并将该数字前置到输出中。我们date +%s --date经常做艰苦的工作，并secs通过调用awk的getline函数将命令的输出捕获到awk变量中。（awk语法为：command | getline variable）。

awk <log1 >log1.new '
{ y = substr($0,3,4); m = $2; d = $3; hms = substr($0,15,8)
  "date \"+%s\" --date \"" d " " m " " y " " hms "\"" | getline secs
  print secs " " $0
}'

第二个awk脚本对第二个文件执行相同的操作，但仅对时间戳记的第一行执行此操作，该脚本保存在awk变量中base。在其他行上，我们只需将分钟和秒的偏移量添加到该基准，并使用date第一个文件的格式将自纪元以来的秒数转换为实际日期。

awk <log2 >log2.new '
/^Timestamp/{ split($5,x,":"); dmy = sprintf("%04d/%02d/%02d",x[3],x[2],x[1])
              split($3,x,":"); hms = sprintf("%02d:%02d:%02d",x[1],x[2],x[3])
              "date \"+%s\" --date \"" dmy " " hms "\"" | getline base
}
/^\[/ { mins = substr($0,2,2); secs = substr($0,5,2);
        tot = base + mins*60+secs
        "date \"+%Y %b %d %H:%M:%S\" --date @" tot | getline date
        print tot " -:" date " " substr($0,8)
}'

然后，按编号字段上的排序将两个文件合并，最后用sed删除编号。

sort -m -n -k1,1 log1.new log2.new |
sed 's/^[^ ]* //'