agent d或agent d (?,?)（它们都是等效的）产生一个PROCEDURE [STRING, INTEGER]，两个操作数d仍为开。由于元组协方差，PROCEDURE [STRING, INTEGER]符合PROCEDURE [STRING]，因此实现了a编译，但是尝试仅使用aTUPLE [STRING]而不是TUPLE [STRING, INTEGER]as操作数来调用代理（b确实如此）会导致运行时异常（可能是catcall）。

逐步关闭代理的操作数的一种方法是将其包装到另一个代理中，并使用一个较少打开的操作数：

b (a_procedure: PROCEDURE [STRING, INTEGER])
local
    l_something_else: INTEGER
    l_partially_closed: PROCEDURE [STRING]
do
    l_something_else := 1

    l_partially_closed := agent (ia_operand_1: STRING; ia_operand_2: INTEGER; ia_procedure: PROCEDURE [STRING, INTEGER])
    do
        ia_procedure.call (ia_operand_1, ia_operand_2)
    end (?, l_something_else, a_procedure)
        -- Notice how only one operand is left open

    z ("a_line", l_partially_closed)
end

或者，l_something_else可以在内联代理中声明：

b (a_procedure: PROCEDURE [STRING, INTEGER])
local
    l_partially_closed: PROCEDURE [STRING]
do
    l_partially_closed := agent (ia_operand_1: STRING; ia_procedure: PROCEDURE [STRING, INTEGER])
    local
        il_something_else: INTEGER
    do
        il_something_else := 1
        ia_procedure.call (ia_operand_1, il_something_else)
    end (?, a_procedure)

    z ("a_line", l_partially_closed)
end

您也可以使用{ROUTINE}.set_operandsand {ROUTINE}.apply，但是我认为它不那么灵活，更容易出错，而且不是线程安全的。

b (a_procedure: PROCEDURE [STRING, INTEGER])
local
    l_something_else: INTEGER
    l_partially_closed: PROCEDURE [STRING]
do
    l_something_else := 1
    a_procedure.set_operands ("some string you will override later", l_something_else)
    z ("a_line", a_procedure)
end

z (a_line: STRING; a_proc: PROCEDURE [STRING]) -- or PROCEDURE [STRING, INTEGER]
do
    -- You have no guarantee that `a_proc' has any operands set (though you could make it a precondition)
    -- This is why it is less safe and less reusable than the previous approach
    check attached a_proc.operands as la_operands then
        la_operands [1] = a_line
    end
    a_proc.apply
end

更新

给定您的实现案例，请参见以“ HERE”开头的注释：

-- Main call
import_from_abb_csv (a_rest_request: REST_REQUEST): detachable like items
    do
        Result := import_from_csv_impl (a_rest_request, agent impl_for_each_csv_line_import_from_abb_csv)
    end

-- Second call
import_from_csv_impl (a_rest_request: REST_REQUEST;
a_procedure: PROCEDURE[DS_ARRAYED_LIST [STRING_8], INTEGER_64, STRING]): detachable like items
    local
        l_csv_handler: UT_CSV_HANDLER
        l_is: KL_STRING_INPUT_STREAM
        l_measuring_point_id: INTEGER_64
        l_s: STRING
        l_partially_closed: PROCEDURE[DS_ARRAYED_LIST[STRING]]
    do
        l_s := "whatever"
        l_measuring_point_id := 12
        create l_csv_handler.make_with_separator (',')

        l_partially_closed := agent (i_al: DS_ARRAYED_LIST[STRING];
                                    ia_measuring_point_id: INTEGER_64;
                                    ia_name: STRING;
                                    ia_procedure: PROCEDURE[DS_ARRAYED_LIST [STRING_8], INTEGER_64, STRING]) -- HERE, change the declared type of `ia_procedure' to match `a_procedure'
            do
                ia_procedure.call (i_al, ia_measuring_point_id, ia_name) -- HERE, add `i_al' to `call'
            end (?, l_measuring_point_id, l_s, a_procedure) -- HERE, add `a_procedure'

        l_csv_handler.read_file (l_is, l_partially_closed)

    end

-- end call

impl_for_each_csv_line_import_from_abb_csv (a_csv_line: DS_ARRAYED_LIST [STRING_8]; a_measuring_point_id: INTEGER_64; l_cu_name: STRING)
    do
        -- do_my_business
    end


-- for information signature of read_file is:
--     read_file (a_file: KI_TEXT_INPUT_STREAM; a_action: PROCEDURE [DS_ARRAYED_LIST [STRING]])