如何正确获取属性名称及其值？

如果您希望为每个可能的属性名称输出一列，而不是仅将其限制为id和version，那么（在XSLT 1.0中）您可以使用一种称为Muenchian Grouping的技术来获取不同的属性名称。

首先定义一个键，以通过属性名称查找属性

<xsl:key name="columns" match="@*" use="local-name()" />

然后，要获取不同的名称（或更确切地说，获取每个不同名称的首次出现），可以定义一个变量，如下所示

<xsl:variable name="columns" select="//@*[generate-id() = generate-id(key('columns', local-name())[1])]" />

然后，要输出列标题，您可以遍历此变量

  <xsl:for-each select="$columns">
     <xsl:sort select="local-name()" />
     <td><xsl:value-of select="local-name()" /></td>
  </xsl:for-each>

对于每一行，您将采用类似的方法。假设您位于子元素上，则可以首先定义一个包含当前元素属性的变量。然后，您将再次遍历column变量，并输出当前元素的相应属性的值

  <xsl:variable name="attributes" select="@*" />
  <xsl:for-each select="$columns">
     <xsl:sort select="local-name()" />
     <td><xsl:value-of select="$attributes[local-name() = local-name(current())]" /></td>
  </xsl:for-each>

试试这个XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output omit-xml-declaration="yes" indent="yes" />
   <xsl:key name="columns" match="@*" use="local-name()" />
   <xsl:variable name="columns" select="//@*[generate-id() = generate-id(key('columns', local-name())[1])]" />
   <xsl:template match="Software">
      <table>
      <tr>
      <td>Software</td>
      <xsl:for-each select="$columns">
         <xsl:sort select="local-name()" />
         <td><xsl:value-of select="local-name()" /></td>
      </xsl:for-each>
      </tr>
      <xsl:apply-templates select="*" />
      </table>
   </xsl:template>

   <xsl:template match="Software/*">
      <tr>
      <td><xsl:value-of select="local-name()" /></td>
      <xsl:variable name="attributes" select="@*" />
      <xsl:for-each select="$columns">
         <xsl:sort select="local-name()" />
         <td><xsl:value-of select="$attributes[local-name() = local-name(current())]" /></td>
      </xsl:for-each>
      </tr>
   </xsl:template>
</xsl:stylesheet>

这应该输出以下内容

<table>
  <tr>
    <td>Software</td>
    <td>id</td>
    <td>version</td>
  </tr>
  <tr>
    <td>MS</td>
    <td/>
    <td>5.2.3.1</td>
  </tr>
  <tr>
    <td>Java</td>
    <td/>
    <td>5.1.0.29</td>
  </tr>
  <tr>
    <td>Oracle</td>
    <td>A</td>
    <td>1.0.1.11</td>
  </tr>
  <tr>
    <td>SQL</td>
    <td>P</td>
    <td>1.0.1.11</td>
  </tr>
</table>

注意，为简便起见，在属性不存在的情况下，我没有包含用于输出“不存在”的代码。但是添加一个检查应该足够简单。（只需将值存储在变量中，然后使用xsl：choose）

编辑：如果您也要限制属性专门用于软件元素，请尝试将键更改为此：

<xsl:key name="columns" match="Software/*/@*" use="local-name()" />