使用VBA在Excel中的SQL表上使用参数化查询

米切尔·沃克(Mitchell Walker)

我有一些代码应该运行我要查询的SQL表的参数化查询。这样做的方式是有一个指定的单元格(Z1),该单元格应从我的其中一列中获取输入值,然后自动更新查询以在excel表中显示结果。我一直收到运行时错误:“ 1004”,它表示这是常规的ODBC错误,但我不确定发生了什么。这是我要连接的数据库:数据库

我正在使用SQL Express,因此服务器为。\ SQLEXPRESS

这是我的代码:

Sub ParameterQueryExample()
'---creates a ListObject-QueryTable on Sheet1 that uses the value in 
'        Cell Z1 as the ProductID Parameter for an SQL Query
'        Once created, the query will refresh upon changes to Z1. 

Dim sSQL As String
Dim qt As QueryTable
Dim rDest As Range


'--build connection string-must use ODBC to allow parameters
Const sConnect = "ODBC;" & _
    "Driver={SQL Server Native Client 10.0};" & _
    "Server=.\SQLEXPRESS;" & _
    "Database=TSQL2012;" & _
    "Trusted_Connection=yes"


'--build SQL statement
sSQL = "SELECT *" & _
        " FROM TSQL2012.Production.Products Products" & _
        " WHERE Products.productid = ?;"


'--create ListObject and get QueryTable
Set rDest = Sheets("Sheet1").Range("A1")
rDest.CurrentRegion.Clear  'optional- delete existing table


Set qt = rDest.Parent.ListObjects.Add(SourceType:=xlSrcExternal, _
    Source:=Array(sConnect), Destination:=rDest).QueryTable


'--add Parameter to QueryTable-use Cell Z1 as parameter
With qt.Parameters.Add("ProductID", xlParamTypeVarChar)
    .SetParam xlRange, Sheets("Sheet1").Range("Z1")
    .RefreshOnChange = True
End With


'--populate QueryTable
With qt
    .CommandText = sSQL
    .CommandType = xlCmdSql
    .AdjustColumnWidth = True  'add any other table properties here
    .BackgroundQuery = False
    .Refresh
End With


Set qt = Nothing
Set rDest = Nothing
End Sub
w

在控制面板\系统和安全性\管理工具中打开“ ODBC数据源管理”程序,并检查您在代码"Driver={SQL Server Native Client 10.0};"指定的驱动程序是否与“驱动程序”选项卡下的驱动程序匹配。不匹配会导致此错误。

本文收集自互联网,转载请注明来源。

如有侵权,请联系 [email protected] 删除。

编辑于
0

我来说两句

0 条评论
登录 后参与评论

相关文章