为什么会出现运行时错误58-在VBA中复制文件时文件已经存在？

移动所有文件

上的Microsoft文档Move：

备注
在文件或文件夹上执行Move方法的结果与使用FileSystemObject.MoveFile或FileSystemObject.MoveFolder执行的操作相同。但是，您应该注意，其他方法也可以移动多个文件或文件夹。

上的Microsoft文档MoveFile：

备注
如果source包含通配符，或者destination以路径分隔符结尾，则假定destination指定了一个现有文件夹，可在其中移动匹配的文件。否则，假定destination是要创建的目标文件的名称。在这两种情况下，移动单个文件都可能发生三件事：

• 如果目标不存在，则文件将被移动。这是通常的情况。
• 如果目标是现有文件，则会发生错误。
• 如果目标是目录，则会发生错误。

调查
fso.MoveFile

• 乍一看似乎fso.MoveFile是要走的路，但这并不是那么简单。
• 第一个问题是，如果源中没有文件，则会发生错误：用解决If .GetFolder(FromPath).Files.Count > 0 Then。
• 第二个（更糟糕的）问题是，如果目标中已存在文件，则无法确定在发生错误之前将复制的内容：未解决。
• 当然，如果您知道目标为空，或者至少没有任何现有文件，那么这是更有效的方法。但是我不会打赌。
• FromPath必须紧跟在PathSeparator且至少要加上一个*，而ToPath必须以结束PathSeparator。

fso.File.Move

• 该fso.File.Move解决方案必须通过文件循环。但是您无需检查文件计数，可以实现If Not .FileExists(ToPath & fsoFile.Name) Then检查目标中是否存在相同名称的文件。
• ToPath必须以结尾PathSeparator，但可以选择后面跟文件名（fsoFile.Name）。

编码

Option Explicit

Sub moveAllFilesFSO()
    
    Dim ws As Worksheet: Set ws = ThisWorkbook.Worksheets("Sheet1")
    Dim FromPath As String: FromPath = ws.Range("E1").Value
    Dim ToPath As String: ToPath = ws.Range("E3").Value
    
    With CreateObject("Scripting.FileSystemObject")
        If .FolderExists(FromPath) And .FolderExists(ToPath) Then
            If .GetFolder(FromPath).Files.Count > 0 Then
                Dim Sep As String: Sep = Application.PathSeparator
                If Right(FromPath, 1) <> Sep Then
                    FromPath = FromPath & Sep
                End If
                FromPath = FromPath & "*" ' "*.*"
                If Right(ToPath, 1) <> Sep Then
                    ToPath = ToPath & Sep
                End If
                .MoveFile FromPath, ToPath
            Else
                Debug.Print "No files found in " & "'" & FromPath & "'."
            End If
        Else
            Debug.Print "At least one of the folders does not exist."
        End If
    End With

End Sub

Sub moveAllFilesFile()
    
    Dim ws As Worksheet: Set ws = ThisWorkbook.Worksheets("Sheet1")
    Dim FromPath As String: FromPath = ws.Range("E1").Value
    Dim ToPath As String: ToPath = ws.Range("E3").Value
    
    With CreateObject("Scripting.FileSystemObject")
        If .FolderExists(FromPath) And .FolderExists(ToPath) Then
            ToPath = .GetFolder(ToPath) & Application.PathSeparator
            Dim fsoFile As Object
            For Each fsoFile In .GetFolder(FromPath).Files
                If Not .FileExists(ToPath & fsoFile.Name) Then
                    fsoFile.Move ToPath ' & fsoFile.Name
                'Else
                    ' File already exists.
                End If
            Next fsoFile
        Else
            Debug.Print "At least one of the folders does not exist."
        End If
    End With

End Sub