如何从所有csv文件中添加列n并存储在另一个csv文件中（标头是该列来自的文件名）？

您可以尝试以下吗？使用GNU中显示的示例编写和测试awk。

awk '
BEGIN{ FS=OFS="," }
FNR==1{
  fileName=(fileName?fileName", ":"")FILENAME
}
{
  max=(max>FNR?max:FNR)
  val[FNR]=(val[FNR] == "" ? "" : val[FNR] OFS) $NF
}
END{
  print fileName
  for(i=1;i<=max;i++){
    print val[i]
  }
}
' *.csv  > output.csv

在显示的示例中，名为的输出文件output.csv将包含以下内容。

input1.csv, input2.csv
5,15
10,20

说明：添加了以上的详细说明。

awk '                                           ##Starting awk program from here.
BEGIN{ FS=OFS="," }                             ##Starting BEGIN section from here and setting field separator and output field separator as comma here.
FNR==1{                                         ##If this is first line of all Input_file
  fileName=(fileName?fileName", ":"")FILENAME   ##Creating fileName which has current Input_file name in it and keep adding it.
}
{
  max=(max>FNR?max:FNR)                         ##Creating max, to get highest number of lines.
  val[FNR]=(val[FNR] == "" ? "" : val[FNR] OFS) $NF        ##Creating val with index of FNR and keep adding values of last field in it.
}
END{                                            ##Starting END block of this program from here.
  print fileName                                ##Printing all file names in outputFile.
  for(i=1;i<=max;i++){                          ##Starting for loop from 1 to max here.
    print val[i]                                ##Printing array val value here.
  }
}
' *.csv > output.csv                            ##Mentioning all *.csv files here.