迭代器的通用可变和非可变参数

kfa6706

这是我不想复制的迭代器：

iterator testI[T](arr: seq[T]): T =
  # I don't want to copy-paste this body
  # In a real world example it might be much bigger
  for i in 0 ..< arr.len:
    yield arr[i]

这适用于：

for i in testI(@[1,2,3]):
  echo i

但不在：

var lst = @[1,2,3]
for i in testI(lst):
  i += 1
  echo i

我可以将迭代器定义替换为：

iterator testI[T](arr: var seq[T]): var T =
  # I don't want to copy-paste this body
  # In a real world example it might be much bigger
  for i in 0 ..< arr.len:
    yield arr[i]

注意，我只是将var添加到参数中并返回。但是，这使得它不再适用于上面的non-var情况。

据我所知，这个问题等同于进行以下工作：

proc foo[A, B](x: A, fn: B) =
  fn(x)

var x = 1
foo(x, proc(x: var int) = x += 1)
foo(1, proc(x: int) = echo x)
assert x != 1

由于某些原因，这甚至行不通：

iterator testI[A, B](arr: A): B =
  # I don't want to copy-paste this body
  # In a real world example it might be much bigger
  for i in 0 ..< arr.len:
    yield arr[i]
var lst = @[1,2,3]
for i in testI[var seq[int], var int](lst):
  i += 1

在D编程语言中，有诸如“自动引用”参数之类的参数，它们基于是否为左值而选择是参考还是值参数。

为什么这是一个难题？我不想每次创建迭代器时都必须复制粘贴该函数。

xbello

通常在Nim中，您会找到两个迭代器：items和mitems，一个用于获取项目而不进行修改，另一个用于修改。在尝试实施一些疯狂的操作之前，我会尽力使用这些过程。

但是有时您必须实现它，因此，每当您发现Nim中的“代码重复”问题可以通过Ctrl-C Ctrl-V解决时，您都应该考虑“模板”。例如

template myCycle =
  ## Long and tedious code here.
  for i in 0 ..< arr.len:
    yield arr[i]

iterator testI[T](arr: seq[T]): T =
  echo "Non-var type"
  myCycle

iterator testI[T](arr: var seq[T]): var T =
  echo "Var type"
  myCycle

var lst1 = @[1,2,3]
for i in testI(lst1):
  echo i

let lst2 = @[1,2,3]
for i in testI(lst2):
  echo i

编译时，Nim会为您复制此处的长代码myCycle，并将其粘贴到两个迭代器中。请注意，您不必传递arr给模板，因为它不是调用而是复制粘贴。

没有什么比最后一个代码块更好地说明我的第一点了。这是等效的代码：

iterator testI[T](a: var openArray[T]): var T {.inline.} =
  var i = 0
  while i < len(a):
    yield a[i]
    inc(i)

var lst = @[1, 2, 3]
for i in testI(lst):
  i += 1

echo lst
# @[2, 3, 4]

这是mitems为openArrays定义的代码（已经通过导入到您的代码中system），因此以上代码可以重写为：

var lst = @[1, 2, 3]
for i in mitems(lst):
  i += 1

echo lst
# @[2, 3, 4]

本文收集自互联网，转载请注明来源。

如有侵权，请联系 [email protected] 删除。

编辑于 2021-01-25

我来说两句

0 条评论

登录后参与评论