gnuplot：如何从文件中绘制一组三角形？

我想不出一步就能做到这一点的方法。数据格式与 gnuplot 的任何绘图样式都不匹配。

一种方法是通过临时文件转换数据。这是一个适用于 5.2 及更高版本的示例。如果您使用的是较新的 gnuplot，则可以替换with polygons为with filledcurves closed.

$DATA << EOD
1 1 2 2 3 1
11 11 14 14 17 11
21 21 22 22 23 21
15 5 16 6 17 5
6 6 7 7 8 6
EOD

set table "temp.dat"
plot $DATA using (sprintf("%g %g\n %g %g\n %g %g\n \n",$1,$2,$3,$4,$5,$6)) with table
unset table

unset key
set style fill solid noborder
plot "temp.dat" using 1:2 with filledcurves closed fillcolor "forest-green"

注意：我最初打算展示使用临时数据块而不是中间临时文件，但这不起作用，因为格式化的输出with table不会将换行符\n转换为空的数据块行。

编辑（显示可变颜色）

包含 RGB 颜色的额外数据字段必须出现在重新格式化数据的每个输入行中，但仅使用每个多边形的第一个顶点的值。此示例中的 sprintf 格式已被修改，以相应地从原始数据文件再现颜色（NB：十六进制整数值），其余多边形顶点中的虚拟值为零。

$DATA << EOD
1 1 2 2 3 1             0x00ffff
11 11 14 14 17 11       0x191970
21 21 22 22 23 21       0x2e8b57
15 5 16 6 17 5          0xffc020
6 6 7 7 8 6             0x8b000
EOD

set table "temp.dat"
plot $DATA using (sprintf("%g %g 0x%x\n %g %g 0\n %g %g 0\n \n",$1,$2,int($7),$3,$4,$5,$6)) with table
unset table

unset key
set style fill solid noborder
plot "temp.dat" using 1:2:3 with filledcurves closed fillcolor rgb variable