该程序从命令行指定的目录中读取文件列表，创建一个哈希数组，其中每个文件都有关键路径，大小和sha256sum。
我正在尝试创建文件的压缩压缩包，其中每个文件的名称均为校验和，并附加了文件的原始扩展名。
我成功创建了文件的压缩包。但是，当我尝试使用Archive :: Tar的重命名方法时，遇到以下错误：
档案中没有这样的文件：./program.pl第62行的'/path/to/file1.txt'。档案中的每个文件都会重复此错误。
use strict;
use warnings;
use Data::Dumper qw(Dumper);
use File::Spec qw(catfile rel2abs);
use Digest::SHA qw(sha256_hex);
use Archive::Tar;
use Archive::Tar::File;
my $dir = $ARGV[0];
my $url = $ARGV[1];
my @AoH;
my @checksumfiles;
my $tar = Archive::Tar->new;
my $archive = "archive.tar.gz";
opendir DIR, $dir or die "cannot open dir $dir: $!\n";
chdir $dir or die "cannot navigate to dir $dir: $!\n";
while(my $file = readdir DIR) {
next unless(-f File::Spec->catfile($dir, $file));
next if($file =~ m/^\./);
my $fullpath = File::Spec->rel2abs($file);
my $fullsize = -s File::Spec->catfile($dir, $file);
my $fullid = sha256_hex($fullpath);
my %hash = (
path => $fullpath,
size => $fullsize,
id => $fullid,
);
push(@AoH, \%hash);
}
my @array;
for my $i(0..$#AoH) {
no warnings 'uninitialized';
my ($ext) = $AoH[$i]{path} =~ (/(\.[^.]+)$/);
my $idext = $AoH[$i]{id} . $ext;
push(@checksumfiles, $idext);
push(@array, $AoH[$i]{path});
}
Archive::Tar->create_archive($archive, COMPRESS_GZIP, @array);
#print Archive::Tar->list_archive($archive, COMPRESS_GZIP), "\n";
for my $i(0..$#array) {
$tar->rename($array[$i], $checksumfiles[$i]);
}
print Dumper sort \@array;
print Dumper sort \@checksumfiles;
#print Dumper sort \@AoH;
存档是使用Class方法 创建的create_archive，而对对象的重命名方法被调用（我的重点是）
将内存中存档的文件重命名为$ new_name。
las，由于从未使用过该对象来写入/读取档案，因此没有内存中的档案。
通常，您可以将存档从磁盘读取到内存中，并在其中获取Archive :: Tar :: File对象。然后重命名文件并写出新的存档。
my @file_objs = $tar->read($archive);
for my $i (0..$#file_objs) {
$file_objs[$i]->rename($checksumfiles[$i]);
}
$tar->write('RENAMED_' . $archive, COMPRESS_GZIP);
这在我的测试中起作用。
但是，如果您确实确实是在创建存档时又进行了额外的读写操作，那么这将非常浪费。在内存中构建存档的合适方法是使用add_files
# In a sub to make sure that renaming stays in order in which files are added
sub archive_renamed {
my ($archive_name, $orig, $new) = @_;
if (@$orig != @$new) {
warn "Unequal length of filename lists";
return;
}
my $tar = Archive::Tar->new;
for my $file (@$orig) {
if (not $tar->add_files($file)) {
warn "Error adding $file: ", $tar->error;
return;
}
}
my @file_objs = $tar->get_files;
for my $i (0..$#file_objs) {
$file_objs[$i]->rename($new->[$i]);
}
$tar->write($archive_name, COMPRESS_GZIP);
if (my $error = $tar->error) {
warn "Error writing $archive_name: $error";
return;
}
return 1;
}
archive_renamed('RENAMED_'.$archive, \@array, \@checksumfiles);
文件的重命名顺序与添加时相同，因此必须确实添加了所有文件，否则我们可能会得到错误的名称。因此，我们会中止添加文件中的任何错误。这就是为什么它也需要放在一个子目录中的原因，这样更改就不会溜进去，最终导致文件重命名混乱。
如果这最终出现在模块中，请使用Carp ::carp而不是warn。如果主代码不应继续出现错误，请使用die（或Carp::croak在模块中）。
如果文档中针对此方法提到的特定属性引起问题（应该不会），您甚至可以首先复制具有新名称的文件，然后使用新名称形成档案（然后删除它们）。这也是额外的工作，但比额外的存档读写更高效。
本文收集自互联网，转载请注明来源。
如有侵权，请联系 [email protected] 删除。
我来说两句