如何在 MS Word 中使用 VBA 选择文档中的所有数学方程？

安德鲁·袁

我对 MS Word 中的 VBA 编辑器很陌生，我想知道是否有办法使用 VBA 选择 Word 文档中的所有数学方程？例如，下面的代码

Sub Change_Equation_Color()
Dim Eq As OMath
For Each Eq In ActiveDocument.OMaths
Eq.Range.Select
Selection.Font.ColorIndex = wdDarkBlue '
Next
End Sub

按顺序选择每个数学方程并将每个方程的颜色更改为“wdDarkBlue”。即使这很好，有没有办法先选择所有方程，然后更改选择的颜色/字体/等？主要原因是如果我的文档有很多方程，那么提供的代码有点慢，因为它必须按顺序遍历每个方程。

编辑。@Timothy Rylatt 提供了一种非常快速且通用的方法，但出于我的目的，我发现以下代码实际上要快得多。

Sub Eq2LM()
    With ActiveDocument.Content.Find
        .ClearFormatting
        .Format = False
        .Font.Name = "Cambria Math"
        .Text = ""
       
        With .Replacement
            .ClearFormatting
            .Font.Name = "Latin Modern Math"
            .Text = ""
        End With
        .Execute Forward:=True, Replace:=wdReplaceAll
    End With
End Sub

“警告”是您的方程必须全部使用“Cambria math”字体，这通常是默认设置。

蒂莫西·赖拉特

无法使用 VBA 创建非连续选择。

使用Selection对象不是一个好习惯，尽管偶尔有必要。通常有更好的替代方案，它们更有效且更不容易出错。例如：

Sub Change_Equation_Color()
    Dim Eq As OMath
    Application.ScreenUpdating = False
    For Each Eq In ActiveDocument.OMaths
        Eq.Range.Font.ColorIndex = wdDarkBlue
    Next
    Application.ScreenUpdating = True
End Sub

本文收集自互联网，转载请注明来源。

如有侵权，请联系 [email protected] 删除。