以字符串形式读取整个文件内容

exebook

您如何将整个文件内容读入Genie中的字符串变量中？

（我在文档中找不到任何内容。这些文档似乎也分散且不完整。）

阿尔托马斯

Genie语言本身没有内置的文件输入/输出。您将需要使用一个库，这就是为什么在很多地方提供文档的部分原因。有很多选择！

通常，GLib库是此类低级功能的良好起点。Genie在其类型系统中大量使用了GLib，并且默认情况下包括到GLib库的绑定。因此，这是使用GLib的FileUtils的示例：

[indent=4]
init
    var filename = "test.txt"
    file_loaded:bool = false
    contents_of_file:string
    try
         file_loaded = FileUtils.get_contents( filename, out contents_of_file )
    except error:FileError
        print( error.message )
    if file_loaded
         print( @"Contents of $filename:

$contents_of_file")

编译：

valac fileutils_example.gs

这个例子利用了Genie的：

用varkeywod进行类型推断
一个out参数contents_of_file
通过contents_of_file在try...except块外声明来确定规则
字符串模板，@""用于调用变量to_string()方法的语法

GLib库包含一个附加组件GIO，它提供异步输入/输出和基于流的API。下一个示例是一个非常基本的示例，与上面的操作相同，但是使用了GIO接口：

[indent=4]
init
    var file = File.new_for_path( "test.txt" )
    file_loaded:bool = false
    contents_of_file:array of uint8
    try
        file_loaded = file.load_contents( null, out contents_of_file, null )
    except error:Error
        print( error.message )
    if file_loaded
        text:string = (string)contents_of_file
        print( @"Contents of $(file.get_basename()):

$text")

编译：

valac --pkg gio-2.0 -X -w fileinputstream_example.gs

注意事项：

--pkg gio-2.0使用GIO库，--pkg glib-2.0在前面的示例中不需要，因为默认情况下已完成
contents_of_file:array of uint8是一个缓冲区和一个out参数load_contents ()
该-X -w选项可valac禁止在guint8期望时从C编译器传递警告char
缓冲区需要转换为字符串： (string)contents_of_file
如果您使用GLib.Mainloop或派生循环，则可以让GIO在后台线程中加载文件：file_loaded = yield file.load_contents_async( null, out contents_of_file, null )
如果要写一个到库的绑定点，null则可null以为参数指定默认值，以便它们成为可选参数，但GIO绑定中未使用该技术。