如何将 Praat 脚本应用于音频文件？

一般答案

你没有。您运行一个脚本，这完全取决于脚本的工作方式、工作对象、获取这些对象的位置、获取方式等。

因此，您始终必须查看如何应用特定脚本，这始终需要弄清楚该脚本如何需要其输入，以及如何达到这一点。

具体答案

您想要的脚本页面说

此命令对每个选定的声音 [执行某些操作]

所以第一件事就是打开你想要的文件并选择它们。

让我们假设您将使用足够少的声音来一次性打开它们。如果您正在处理大量声音文件，或者文件太大而无法保存在内存中，则必须将作业分成更小的块。

一种方法是使用包装脚本打开您的文件，选择它们，然后执行您想要的其他脚本：

# Get a list of all your files
files = Create Strings as file list: "list", "/some/path/*.wav"
total_files = Get number of strings

# Open each of them
for i to total_files
    selectObject: files
    filename$ = Get string: i
    sounds[i] = Read from file: "/some/path/" + filename$    
endfor

# Clear the selection
nocheck selectObject(undefined)

# Add each sound to your selection
for i to total_files
    plusObject: sounds[i]
endfor

# Run your script
runScript: path_to_script$, ...
# where the ... is the list of arguments your script expects

# In your specific case, it would be something like
runScript: preferencesDirectory$ + "/plugin_VocalToolkit/changeformants.praat",
    ... 500, 1500, 2500, 0,     0,    5500, "yes", "yes"
#      ,-´  ,-´  ,--´ ,--´    ,-´       ^     ^      ^
# New F1,  F2,  F3,  F4, and F5 means   |     |      |
#                               Max formant   |      |
#                       Process only voiced parts    |
#                             Retrieve intensity contour

# Do something with whatever the script gives you

我的 Praat 很生疏，但这至少应该让你知道该怎么做（免责声明：我没有运行上述任何一个，但概念应该没问题）。

将该“包装器”脚本存储在某处后，您可以从命令行执行它：

$ praat /path/to/wrapper.praat