使用 range.find 时键入不匹配错误

这里发生了几件事：

• ActiveSheet是 的属性Excel.Application，不是Workbook。所以用OXL.ActiveSheet
• Word 不知道ActiveCell，所以使用OXL.ActiveCell
• 即便如此，也After必须是搜索范围内的单元格
• Word 不知道Find. 所以使用那里的值。

所以，改为

OXL.ActiveSheet.Range("E:E").Find(What:=OXL.ActiveSheet.Range("A1").Value, After:=OXL.Range("E1"), LookIn:=-4123, LookAt:=2, SearchOrder:=1, SearchDirection:=1, MatchCase:=False, SearchFormat:=False).Activate

毕竟，考虑

• 你应该声明你所有的变量
• 您应该指定工作簿的完整路径，而不是依赖默认位置
• 当您打开这本书时，您如何知道哪个工作表将处于活动状态？指定你想要的
• 你怎么知道Find会找到结果？允许失败的可能性
• 您应该获得对找到的单元格的引用，而不是Activate对其进行操作
• 考虑早期绑定代码，而不是后期绑定。有充分的理由使用它们。
• GetObject(, "Excel.Application")假设有一个 Excel 实例正在运行。如果没有呢？你的代码应该处理这种情况

有点像

Sub Demo()
    Dim oXL As Object ' Excel.Application
    Dim oWB As Object ' Excel.Workbook
    Dim oWB2 as Object ' Excel.Workbook
    Dim oSH As Object ' Excel.Worksheet
    Dim oSearchRange As Object ' Excel.Range
    Dim oRng As Object ' Excel.Range

    Set oXL = GetObject(, "Excel.Application")
    Set oWB = oXL.Workbooks.Open("C:\Full\Path\To\All Defaults.xls")
    Set oWB2 = oXL.Workbooks.Open("C:\Full\Path\To\1.xlsx")
    Set oSH = oWB.Worksheets("SpecifySheet")
    Set oSearchRange = oSH.Range("E:E")
    Set oRng = oSearchRange.Find( _
      What:=oSH.Range("A1").Value, _
      After:=oSearchRange.Cells(1, 1), _
      LookIn:=-4123, _
      LookAt:=2, _
      SearchOrder:=1, _
      SearchDirection:=1, _
      MatchCase:=False, _
      SearchFormat:=False)

    If Not oRng Is Nothing Then
        oRng.Activate
    End If
End Sub