(VB.NET) 将文本文件的下半部分显示到列表框

首先，我开设了 2 个课程，一个 Runner 和一个 School。这些具有文本文件中可用的属性。作为课程的一部分，我添加了一个覆盖 .ToString 的函数。这是用于调用 .ToString 进行显示的列表框。

接下来我做了一个函数来读取文件中的所有数据。这对于 File.ReadLines 方法非常简单。

然后我创建了 2 个变量 List(Of T) T 代表类型。我们的类型是跑步者和学校。我使用 List(Of T) 而不是数组，因为我不必担心列表的大小。没有 ReDim Preserve，只需继续添加项目。FillList 方法将数据添加到列表中。首先，我必须找到学校结束和跑步者开始的地方。我使用了 Array.FindIndex 方法，它有点不同，因为第二个参数是谓词。检查一下。现在我们知道要用于每个列表的行的索引并使用 For...Next 循环。在每个循环中都会创建一个类的实例并设置属性。最后，新对象被添加到列表中。

最后我们用一个简单的.AddRange 和lists.ToArray 填充列表框。请注意，我们正在添加整个对象、属性和所有内容。巧妙的是我们可以从列表框项中访问属性。查看 SelectedIndexChanged 事件。您可以使用 Runner 列表框执行相同的操作。

抱歉，我不能只使用您的代码。我几乎忘记了旧的 vb6 方法。InStr、Mid 等。最好使用 .net 方法。当老板说“用 C# 重写整个应用程序”时，它使您的代码更具可移植性

Public Class Runner
    Public Property BibNum As Integer
    Public Property SchoolCode As String
    Public Property FirstName As String
    Public Property LastName As String
    Public Overrides Function ToString() As String
        'The listbox will call .ToString when we add a Runner object to determin what to display
        Return $"{FirstName} {LastName}" 'or $"{LastName}, {FirstName}"
    End Function
End Class

Public Class School
    Public Property Code As String
    Public Property Name As String
    Public Property CoachFName As String
    Public Property CoachLName As String
    Public Property ADFName As String
    Public Property ADLName As String

    'The listbox will call .ToString when we add a School object to determin what to display
    Public Overrides Function ToString() As String
        Return Name
    End Function

End Class

Private Runners As New List(Of Runner)
Private Schools As New List(Of School)
Private Function ReadData(path As String) As String()
    Dim lines = File.ReadLines(path).ToArray
    Return lines
End Function

Private Sub FillLists(data As String())
    Dim location = Array.FindIndex(data, AddressOf FindRosterLine)
    'The first line is the title so we don't start at zero
    For index = 1 To location - 1
        Dim SplitData = data(index).Split("|"c)
        Dim Schl As New School
        Schl.Code = SplitData(0)
        Schl.Name = SplitData(1)
        Schl.CoachFName = SplitData(2)
        Schl.CoachLName = SplitData(3)
        Schl.ADFName = SplitData(4)
        Schl.ADLName = SplitData(5)
        Schools.Add(Schl)
    Next
    For index = location + 1 To data.GetUpperBound(0)
        Dim SplitData = data(index).Split("|"c)
        Dim Run As New Runner
        Run.BibNum = CInt(SplitData(0))
        Run.SchoolCode = SplitData(1)
        Run.FirstName = SplitData(2)
        Run.LastName = SplitData(3)
        Runners.Add(Run)
    Next
End Sub

Private Function FindRosterLine(s As String) As Boolean
    If s.Trim.StartsWith("# Roster") Then
        Return True
    Else
        Return False
    End If
End Function

Private Sub FillListBoxes()
    Dim arrRunners As Runner() = Runners.ToArray
    Dim arrSchools As School() = Schools.ToArray
    ListBox1.Items.AddRange(arrSchools)
    ListBox2.Items.AddRange(arrRunners)
End Sub

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    Dim arrRunner = ReadData("Runners.txt")
    FillLists(arrRunner)
    FillListBoxes()
End Sub

Private Sub ListBox1_SelectedIndexChanged(sender As Object, e As EventArgs) Handles ListBox1.SelectedIndexChanged
    Dim Schl = DirectCast(ListBox1.SelectedItem, School)
    TextBox1.Text = Schl.CoachLName
    TextBox2.Text = Schl.Code
End Sub