我有通过 .xlsx 文件从在线资源导入的运动数据。每次观察都是 NFL（美式足球）比赛中的一个点球。为了稍后merge使用另一个数据集，我需要在两个文件之间匹配某些变量/值。但是，我遇到了一个变量的问题。
在有问题的主要数据集（最初提到的惩罚数据集）中，我的最终目标是创建两个变量，Minute和Second，它们的类型是byte和format %8.0g。这将使它们与目标数据集中的各个变量完美对应。我有所需的可用信息，即 NFL 比赛给定四分之一的剩余时间，但它以一种奇怪的方式存储，而且我在转换内容时遇到了麻烦。
数据存储在一个名为 的变量中Time。显然，从原始 .xlsx 文件导入的数据看起来不错。例如，第一个观察结果为“12:21”，表示该季度还剩 12 分 21 秒。然而，当从 .xlsx 表导入时，Stata 假设该变量Time是一个以 hh:mm 度量的日期/时间变量，因此为其分配类型double和格式%tchh:MM。
最后，我真的不关心正确格式化这个Time变量，但我需要以某种方式使这场比赛的需要Minute和Second目标文件的列。我尝试了几种不同的方法，但到目前为止似乎没有任何效果。
如果 Stata 将分钟和秒误读为小时和分钟，并且（正如它所做的那样）以毫秒为单位存储日期时间，那么它就会关闭 60（分钟/小时）x 1000（毫秒/秒）= 60000。所以，考虑
. clear
. set obs 1
number of observations (_N) was 0, now 1
. gen double wrong = clock("1jan1960 12:21:00", "DMY hms")
. format wrong %tchh:MM
. clonevar alsowrong = wrong
. format alsowrong %15.0f
. list
+------------------+
| wrong alsowr~g |
|------------------|
1. | 12:21 44460000 |
+------------------+
. gen right = wrong/60000
. gen byte Minute = floor(right/60)
. gen byte Second = mod(right, 60)
. list
+--------------------------------------------+
| wrong alsowr~g right Minute Second |
|--------------------------------------------|
1. | 12:21 44460000 741 12 21 |
+--------------------------------------------+
我无法轻松评论您的导入，因为既没有提供导入的文件，也没有提供确切的导入代码作为示例。
编辑另一种方法：
. gen alsoright = string(wrong, "%tchh:MM")
. gen minute = real(substr(alsoright, 1, strpos(alsoright, ":") - 1))
. gen second = real(substr(alsoright, strpos(alsoright, ":") + 1, .))
. l alsoright minute second
+----------------------------+
| alsori~t minute second |
|----------------------------|
1. | 12:21 12 21 |
+----------------------------+
本文收集自互联网，转载请注明来源。
如有侵权，请联系 [email protected] 删除。
我来说两句