VIM 中的持久（粘性）第一行或第一列

感谢@DoktorOSwaldo 上面的评论，这是我能做的最好的事情。F2 和 F3 在绑定的第一列（根据给定的分隔符）和绑定的第一行之间切换。F4 破坏两者：

hi cursorcolumn ctermbg=red
function Title_destroy()
    if( winnr() == 1 )
        return 0
    endif
    let oldpos = getpos('.')
    wincmd k
    wincmd j
    hide
    call setpos('.',oldpos)
    set nocul
    set nocuc
endfunction
function Title_bar()
    if( winnr() > 1 )
        call Title_destroy()
    endif
    set nowrap
    split %
    set scb
    wincmd j
    set scb
    wincmd _
    set scrollopt=hor
    set cuc
endfunction
function Col_bar(delim)
    if( winnr() > 1 )
        call Title_destroy()
    endif
    set nowrap
    let oldpos = getpos('.')
    call setpos('.',[oldpos[0],oldpos[1],0,oldpos[3]])
    let width = searchpos(a:delim)[1]+3
    call setpos('.',oldpos)
    vsplit %
    exe 'vertical resize' width
    set scb
    wincmd l
    set scb
    set scrollopt=ver
    set cul
endfunction
nnoremap <F2> :call Title_bar()<CR>
nnoremap <F3> :call Col_bar(nr2char(getchar()))<CR>
nnoremap <F4> :call Title_destroy()<CR>

我想不出同时做这两个scrollopt事情的方法，因为这是一个全球性的事情。如果有人弄清楚，请发表评论或回答。也许以某种方式重载窗口滚动以scrollopt根据滚动方向更改。现在这足以处理大表（对我而言）。

升级

1. 接受数字可选参数相当容易 - 从第一次更改行/列。
2. 既有粘性行又有粘性列。