在 SeclectedItem 上绑定的 ComboBox 无法更改选择

山姆·马金

我有一个简单的表单,它使用 DataBinding 绑定到对象集合。最初我不希望 ComboBox 显示选择,所以我将其选定的索引设置为 -1。但是,当 ComboBox 被选中时,我无法在不选择值的情况下取消选择它。

如何在不选择值的情况下取消选择 ComboBox(选择其他控件)?

要重新创建,请创建一个新的 winform,添加一个 ComboBox 和一个 TextBox,然后使用以下代码:

Imports System.Collections.Generic

Public Class Form1

    Public Property f As Person

    Public Sub New()
        ' This call is required by the designer.
        InitializeComponent()

        ' Add any initialization after the InitializeComponent() call.
        Dim db As New People
        ' ComboBox1.CausesValidation = False
        ComboBox1.DataSource = db
        ComboBox1.DisplayMember = "Name"
        ComboBox1.DataBindings.Add("SelectedItem", Me, "f", False, DataSourceUpdateMode.OnPropertyChanged)
        ComboBox1.SelectedIndex = -1
    End Sub

End Class

Public Class Person
    Public Property Name As String
End Class

Public Class People
    Inherits List(Of Person)

    Public Sub New()
        Me.Add(New Person With {.Name = "Dave"})
        Me.Add(New Person With {.Name = "Bob"})
        Me.Add(New Person With {.Name = "Steve"})
    End Sub
End Class

当窗体启动时,应该选择 ComboBox,而不能选择 TextBox。

我发现将 ComboBox 上的 CausesValidation 切换为 False 可以解决问题,但会破坏数据绑定。

山姆·马金

找到了解决办法!(谢谢伊万!)

如果 ComboBox 在验证时作为 SelectedIndex 为 -1,则暂时禁用绑定。

        AddHandler ComboBox1.Validating, AddressOf DisableBindingWhenNothingSelected
        AddHandler ComboBox1.Validated, AddressOf DisableBindingWhenNothingSelected

    ''' <summary>
    ''' Temporarily disables binding when nothing is selected.  
    ''' </summary>
    ''' <param name="sender">Sender of the event.</param>
    ''' <param name="e">Event arguments.</param>
    ''' <remarks>A list bound ComboBox (and more generically ListControl) cannot be deselected, 
    ''' because CurrencyManager does not allow setting the Position to -1 when the underlying list Count is > 0. 
    ''' This should be bound to the Validating and Validated events of all ComboBoxes that have an initial SelectedIndex of -1.</remarks>
    Protected Sub DisableBindingWhenNothingSelected(sender As Object, e As EventArgs)
        Dim cb As ComboBox = DirectCast(sender, ComboBox)
        If cb.SelectedIndex = -1 Then
            If (cb.DataBindings.Count = 0) Then Exit Sub
            If cb.DataBindings(0).DataSourceUpdateMode = DataSourceUpdateMode.Never Then
                cb.DataBindings(0).DataSourceUpdateMode = DataSourceUpdateMode.OnPropertyChanged
            Else
                cb.DataBindings(0).DataSourceUpdateMode = DataSourceUpdateMode.Never
            End If
        End If
    End Sub

本文收集自互联网,转载请注明来源。

如有侵权,请联系 [email protected] 删除。

编辑于
0

我来说两句

0 条评论
登录 后参与评论

相关文章