delphi在TDictionary中使用记录作为键

r_j 发表于 Dev

您可以将记录用作TDictionary中的键值吗？我想根据字符串，整数和整数的组合找到对象。

TUserParKey=record
  App:string;
  ID:integer;
  Nr:integer;
end;

...

var
  tmpKey:TUserParKey;
  tmpObject:TObject;
begin
  tmpObject:= TTObject.Create(1); 
  tmpKey.App:='1';
  tmpKey.ID :=1;
  tmpKey.Nr :=1;

  DTUserPars.Add(tmpKey,tmpObject)

...

var
  tmpKey:TUserParKey;
begin
  tmpKey.App:='1';
  tmpKey.ID :=1;
  tmpKey.Nr :=1;

  if not DTUserPars.TryGetValue(tmpKey,Result) then begin
    result := TTObject.Create(2); 
  end;

这将返回对象2。

斯蒂芬·格里恩克

是的，您可以将记录用作TDictionary中的键，但是在创建字典时应提供自己的IEqualityComparer，因为记录的默认记录只是对记录进行了哑巴的二进制比较。对于包含字符串的记录，此操作将失败，因为它仅比较该字符串的指针，即使该字符串包含相同的值，该指针也可能会有所不同。

这样的比较器如下所示：

type
  TUserParKeyComparer = class(TEqualityComparer<TUserParKey>)
    function Equals(const Left, Right: TUserParKey): Boolean; override;
    function GetHashCode(const Value: TUserParKey): Integer; override;
  end;

function TUserParKeyComparer.Equals(const Left, Right: TUserParKey): Boolean;
begin
  Result := (Left.App = Right.App) and (Left.ID = Right.ID) and (Left.Nr = Right.Nr);
end;

function TUserParKeyComparer.GetHashCode(const Value: TUserParKey): Integer;
begin
  Result := BobJenkinsHash(PChar(Value.App)^, Length(Value.App) * SizeOf(Char), 0);
  Result := BobJenkinsHash(Value.ID, SizeOf(Integer), Result);
  Result := BobJenkinsHash(Value.Nr, SizeOf(Integer), Result);
end;

本文收集自互联网，转载请注明来源。

如有侵权，请联系 [email protected] 删除。