由于驱动程序认为我正在使用整数/数字并显示空值而不是文本,因此无法使用ADO从CSV读取数据

用户名

我正在尝试使用ADO将一系列文本文件读入工作表中。当特定列中的大多数数据是整数时,我遇到了问题。到达字符串时,它将给出空值(空白单元格)。

根据微软的支持(Ado混合数据类型),这是很常见的,解决方案是设置IMEX = 1我尝试了一下,但是没有用。

我一直在寻找其他线程寻找答案,并遇到了这个答案(其他线程),作者说要更改TypeGuessRows为“让Jet来检测是否存在混合类型的情况,并欺骗Jet来检测某种数据类型”。但是,这也不起作用。

下面是我的VBA代码。任何帮助,将不胜感激

Sub query_text_file(WorkingSheet As String, Col As String, Row As Integer, fileName As String, firstOrLast As Integer)

Dim strPath As String
Dim ws As Worksheet

strToolWkbk = fileName
strPath = ThisWorkbook.Path & "\Excel_Barcode_Files"
Set ws = Worksheets(WorkingSheet)

'Need to reference the:
'   Microsoft ActiveX Data Objects 2.5 Library
Dim s_rst As ADODB.Recordset
Dim s_cnn As ADODB.Connection 's for sub connection
Dim intRow As Integer

Const adOpenStatic = 3
Const adLockOptimistic = 3
Const adCmdText = &H1

Set s_cnn = New ADODB.Connection

s_cnn = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strPath & ";" _
& "Extended Properties=""text;HDR=Yes;IMEX=1;TypeGuessRows=12;FMT=Delimited"";"

s_cnn.Open
Set s_rst = New ADODB.Recordset


strSQL = "SELECT * FROM " & strToolWkbk


s_rst.Open strSQL, _
    s_cnn, adOpenStatic, adLockOptimistic, adCmdText

intRow = Row

s_rst.MoveFirst


Do Until s_rst.EOF
    ws.Range(Col & intRow) = s_rst(0)
    ws.Range(Chr(Asc(Col) + 1) & intRow) = s_rst(1)
    intRow = intRow + 1
    s_rst.MoveNext
Loop

s_rst.Close
s_cnn.Close

Set s_rst = Nothing
Set s_cnn = Nothing

End Sub

这是一个示例文本文件。该代码读取除“ P”之外的所有内容

test test
P,0
1,1
5,2
6,3
用户名

基本上,不要依赖MSDN上解释的注册表项

您需要创建一个Schema.ini文件,并将其放置在与所有文本文件相同的文件夹中。在其中Schema.ini指定文本文件中所有列的类型-显式地执行此操作是一个更安全的选择,而不是让驱动程序为列确定正确的类型...

假设您的桌面上有一些txt文件,请打开记事本,然后复制并粘贴以下内容-确保调整[test.txt]部分以匹配实际txt文件的名称并将其另存为:Schema.ini

[test.txt]
Format=CSVDelimited

Col1=Column1 Text
Col2=Column2 Text

确保在parth的末尾添加另一个斜杠strPath也在文章中指出

strPath = ThisWorkbook.Path & "\Excel_Barcode_Files\"

*请记住,我在与您不同的位置工作-本示例使用的是我的桌面,并且我的文本文件名为 test.txt

现在,您已经Schema.ini可以修改连接字符串并删除一些不需要的参数,因为它们存在于Schema.ini

因此,基本上基于上述假设的SSCCE将是:

Sub Main()

    Cells.ClearContents

    Dim cn As New ADODB.Connection
    Dim rs As New ADODB.Recordset

    Dim thePath As String
    thePath = "C:\Users\" & Environ("USERNAME") & "\Desktop\"


    cn.ConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & thePath & ";" _
                        & "Extended Properties=""text;HDR=No;"""

    cn.Open

    Dim sql As String
    sql = "SELECT * FROM test.txt"

    ' populate the recordset
    rs.Open sql, cn, adOpenStatic, adLockOptimistic, &H1

    ' copy the recordset starting at Range("A1") - assuming there are no headers - see HDR = No;
    Range("A1").CopyFromRecordset rs

    rs.Close
    Set rs = Nothing
    cn.Close
    Set cn = Nothing

End Sub

现在,运行此命令后,您应该会看到所有值,包括缺少的值P

在此处输入图片说明

本文收集自互联网,转载请注明来源。

如有侵权,请联系 [email protected] 删除。

编辑于
0

我来说两句

0 条评论
登录 后参与评论

相关文章