使用Saxon，在XSLT中递增或递减全局变量

据我所知，没有办法在撒克逊人中使用Javascript。

如果要在Saxon 9（EE或PE）中使用可分配和可变的变量，则可以使用

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:saxon="http://saxon.sf.net/"
    xmlns:mf="http://example.com/mf"
    extension-element-prefixes="saxon"
    exclude-result-prefixes="xs saxon mf"
    version="2.0">

    <xsl:variable name="counter" as="xs:integer" select="0" saxon:assignable="yes"/>

    <xsl:function name="mf:incr" as="xs:integer">
        <saxon:assign name="counter" select="$counter + 1"/>
        <xsl:sequence select="$counter"/>
    </xsl:function>

    <xsl:function name="mf:decr" as="xs:integer">
        <saxon:assign name="counter" select="$counter - 1"/>
        <xsl:sequence select="$counter"/>
    </xsl:function>

    <xsl:template match="/" name="main">
        a)<xsl:value-of select="mf:incr()"/>
        b)<xsl:value-of select="mf:incr()"/>
        c)<xsl:value-of select="mf:decr()"/>
    </xsl:template>

</xsl:stylesheet>

有关尝试引入副作用的信息，请参见http://saxonica.com/html/documentation/extensions/instructions/assign.html中的警告和说明。您可能希望编辑问题以解释您的XML输入和所需的输出，以及为什么您认为需要这样的计数器变量，希望我们可以再显示一个纯XSLT 2.0解决方案，而不是使用可分配的变量。

至于您对某些输入元素进行处理和编号的要求，样式表

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="xs"
    version="2.0">

    <xsl:output indent="yes"/>

    <xsl:template match="entity">
        <root>
            <xsl:apply-templates select="record[. > 14]"/>
            <xsl:apply-templates select="record[. &lt; 14]"/>
        </root>
    </xsl:template>

    <xsl:template match="record">
        <xsl:copy>
            <line-num>
                <xsl:value-of select="position()"/>
            </line-num>
            <value>
                <xsl:value-of select="."/>
            </value>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

当针对输入运行时

<entity>
    <record>10</record>
    <record>15</record>
    <record>19</record>
    <record>7</record>
    <record>4</record>
    <record>14</record>
    <record>24</record>
</entity>

输出

<root>
   <record>
      <line-num>1</line-num>
      <value>15</value>
   </record>
   <record>
      <line-num>2</line-num>
      <value>19</value>
   </record>
   <record>
      <line-num>3</line-num>
      <value>24</value>
   </record>
   <record>
      <line-num>1</line-num>
      <value>10</value>
   </record>
   <record>
      <line-num>2</line-num>
      <value>7</value>
   </record>
   <record>
      <line-num>3</line-num>
      <value>4</value>
   </record>
</root>

其他选项使用例如xsl:number count="entity[. < 14]"。

至于您的最新要求，我认为position()只要选择要处理的元素（例如样式表），您仍然可以使用来处理

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="2.0">

    <xsl:output method="text"/>

    <xsl:template match="/">
        <xsl:apply-templates select="/root/entity[1]//record[. > 15], /root/entity[2]//record[. &lt; 10]"/>
    </xsl:template>

    <xsl:template match="record">
        <xsl:value-of select="concat(position(), ' ', ., '&#10;')"/>
    </xsl:template>

</xsl:stylesheet>

当应用于输入时

<root>
    <entity>
        <record>10</record>
        <record>15</record>
        <record>19</record>
        <record>7</record>
        <record>20</record>
        <record>14</record>
        <record>24</record>
        <entity>
            <record>30</record>
            <record>3</record>
        </entity>
    </entity>
    <entity>
        <record>5</record>
        <record>17</record>
        <record>19</record>
        <record>6</record>
        <record>70</record>
        <record>9</record>
        <record>35</record>
        <entity>
            <record>15</record>
            <record>2</record>
        </entity>
    </entity>
</root>

输出（使用像Saxon 9这样的XSLT 2.0处理器）

1 19
2 20
3 24
4 30
5 5
6 6
7 9
8 2