如何使用Groovy访问Jenkins服务器的用户特定视图的作业？

鹰彩虹

目前，我需要在Jenkins服务器上触发状态为“图标红色”的所有作业，这些作业由给定的特定于用户的视图（my-views）选择。问题在于列表很长，我们不想手动触发它们。这就是为什么我想到使用Groovy脚本（Jenkins的脚本控制台）的想法。

我可以使用以下代码触发给定全局视图的所有红色作业：

def viewName = "globalviewname"
def jobsToBuild = Jenkins.instance.getView(viewName).items.findAll { job ->
    job.getBuildStatusIconClassName() == "icon-red"
}

jobsToBuild.each { job ->
    println "Scheduling matching job ${job.name}"
    job.scheduleBuild(new Cause.UserIdCause())
}

但是，我缺少如何访问当前用户视图的方法（以后将成为参数）：调用

Jenkins.instance.getViews()

仅提供所有全局视图的列表。我目前正在和

Jenkins.instance.getMyViewsTabBar()

（另请参见http://javadoc.jenkins-ci.org/jenkins/model/Jenkins.html#getMyViewsTabBar（）），但显然我没有把握住它。

有什么线索如何访问与用户特定的列表视图关联的项目列表？

鹰彩虹

我想自己设法找到了它：

Jenkins中用户的个人视图是给定用户的UserProperty的一部分。
每个用户可能有多个UserProperty-正确的UserProperty是MyViewProperty。

假设变量username包含我们要获取的视图的用户名，并且变量viewname包含我们要检索的视图的名称，那么以下典型的Groovy编码对我有用：

def user = User.get(username, false, null)
if (user == null) {
  throw new Error("User does not exists")
}
println "Reading data from user "+user.toString()

// retrieve all UserProperties of this user and filter on the MyViewsProperty
def allMyViewsProperties = user.getAllProperties().findAll { 
  uprop -> (uprop instanceof hudson.model.MyViewsProperty) 
}
if (allMyViewsProperties.size() == 0) {
  throw new Error("MyViewsProperties does not exists")
}

// retrieve all views which are assigned to the MyViewsProperty.
// note that there also is a AllViewsProperty
def allPersonalViewsOfUser = allMyViewsProperties[0].getViews()

// further narrow down only to ListViews (special use case for me)
def allPersonalListViews = allPersonalViewsOfUser.findAll { 
  view -> view instanceof hudson.model.ListView 
}

// based on its name, filter on the view we want to retrieve
def listView = allPersonalListViews.findAll { view -> viewname.equals(view.getViewName()) }
if (listView.size() != 1) {
  throw new Error("selected view does not exist");
}

// get the view now
def view = listView[0]

有了所有这些，现在很容易通过运行以下命令以该视图的红色状态触发所有作业

def jobsToBuild = view.items.findAll { job ->
    job.getBuildStatusIconClassName() == "icon-red"
}

jobsToBuild.each { job ->
    println "Scheduling matching job ${job.name}"
    job.scheduleBuild(new Cause.UserIdCause())
}

本文收集自互联网，转载请注明来源。

如有侵权，请联系 [email protected] 删除。