降序列表框项目Delphi XE8

您可以采用许多不同的方法来解决此问题。您已经显示了一种方法。您可以切换到虚拟列表框，并将数据存储在保持顺序的数据结构中。您可以就地对列表进行排序。

就我个人而言，查看您的代码以创建一个新列表以执行排序时，我感到有些不安。而且，通过使用时间戳记的文本表示，甚至会更加烦躁。如果列表中有大量项目，则虚拟模式会更有效。

但是，我将演示一种非常灵活的方法来就地对列表进行排序。让我们从我的答案中的代码开始：https : //stackoverflow.com/a/21702570/505088。为了自给自足，让我们在这里重现代码，并对其进行稍作修改以使用参考过程：

type
  TCompareIndicesFunction = reference to function(Index1, Index2: Integer): Integer;
  TExchangeIndicesProcedure = reference to procedure(Index1, Index2: Integer);

procedure QuickSort(Count: Integer; Compare: TCompareIndicesFunction; 
  Exchange: TExchangeIndicesProcedure);

  procedure Sort(L, R: Integer);
  var
    I, J, P: Integer;
  begin
    repeat
      I := L;
      J := R;
      P := (L+R) div 2;
      repeat
        while Compare(I, P)<0 do inc(I); 
        while Compare(J, P)>0 do dec(J); 
        if I<=J then 
        begin
          if I<>J then 
          begin
            Exchange(I, J);
            //may have moved the pivot so we must remember which element it is
            if P=I then
              P := J
            else if P=J then
              P := I;
          end;
          inc(I);
          dec(J);
        end;
      until I>J;
      if L<J then 
        Sort(L, J); 
      L := I;
    until I>=R;
  end;

begin
  if Count>0 then
    Sort(0, Count-1);
end;

这里的关键思想是将排序算法与数据存储区分开来。这就是给我们带来灵活性的原因。

接下来，我们需要实现比较和交换功能。像这样：

var
  Compare: TCompareIndicesFunction;
  Exchange: TExchangeIndicesProcedure;

Compare := 
  function(Index1, Index2: Integer): Integer
  var
    dt1, dt2: TDateTime;
  begin
    dt1 := TFile.GetLastAccessTime(lb.Items[Index1]);
    dt2 := TFile.GetLastAccessTime(lb.Items[Index2]);
    if dt1=dt2 then begin
      Result := 0;
    end else if dt2<dt1 then begin
      Result := -1
    end else begin
      Result := 1;
    end;
  end;

Exchange := 
  procedure(Index1, Index2: Integer)
  begin
    lb.Items.Exchange(Index1, Index2);
  end;

请注意，我正在比较时间戳的数字值，感觉更令人愉悦。如果我把命令放到最前面（我总是在使用排序比较功能），那么如何逆转它应该很明显。

最后我们可以像这样排序：

QuickSort(lb.Count, Compare, Exchange);

此代码应放在您的代码中DescendLZB，以便可以捕获列表框。此外，该lb参数不应是var参数，因为您不想修改其值。

所有这些看起来像这样：

procedure TBCSLBDemoC.DescendLZB(lb: TListBox);
var
  Compare: TCompareIndicesFunction;
  Exchange: TExchangeIndicesProcedure;
begin
  Compare := 
    function(Index1, Index2: Integer): Integer
    var
      dt1, dt2: TDateTime;
    begin
      dt1 := TFile.GetLastAccessTime(lb.Items[Index1]);
      dt2 := TFile.GetLastAccessTime(lb.Items[Index2]);
      if dt1=dt2 then begin
        Result := 0;
      end else if dt2<dt1 then begin
        Result := -1
      end else begin
        Result := 1;
      end;
    end;

  Exchange := 
    procedure(Index1, Index2: Integer)
    begin
      lb.Items.Exchange(Index1, Index2);
    end;
  end;

  QuickSort(lb.Count, Compare, Exchange);
end;